COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	IFCR NOT DECLARATION($$PRGID) THENC
C00006 ENDMK
C⊗;
IFCR NOT DECLARATION($$PRGID) THENC
ENTRY;

BEGIN "HELP"	ENDC
DEFINE $$HELP=TRUE;
REQUIRE "HEADER.SAI" SOURCE_FILE;

INTEGER $HLPTAB,$FFTAB;
PROCEDURE INIHLP;
BEGIN
	SETBREAK ($HLPTAB←GETBREAK,"\",NULL,"INS");
	SETBREAK ($FFTAB←GETBREAK,FF,NULL,"INS");
END;

REQUIRE INIHLP INITIALIZATION;

INTERNAL PROCEDURE HLPMSG(INTEGER HELP1,HELP2(0));
	BEGIN
	INTEGER HLPCH,BRCHR,EOF,I;
	INTEGER NUM;STRING TEMP;
	OPEN(HLPCH←GETCHAN,"DSK",0,3,0,4000,BRCHR,EOF);
	LOOKUP(HLPCH,"HELP[PNT,HE]",EOF);
	NUM←9;
	WHILE NUM<50 DO
	  IF HELP1≤NUM 
	   THEN BEGIN
		NUM←NUM-9; 
		WHILE NUM≠HELP1 DO 
		  BEGIN TEMP←INPUT(HLPCH,$HLPTAB);
			NUM←NUM+1;
		  END;
		IF HELP2
		   THEN BEGIN
			FOR I←HELP1 STEP 1 UNTIL HELP2 
			    DO OUTSTR(INPUT(HLPCH,$HLPTAB));
			RETURN;
		END
		   ELSE BEGIN OUTSTR(INPUT(HLPCH,$HLPTAB));RETURN;END;
		END
	   ELSE BEGIN
		TEMP←INPUT(HLPCH,$FFTAB);
		NUM←NUM+10;
		END;
	RELEASE(HLPCH);
	END;

INTERNAL PROCEDURE HLPDO(STRING ANSWER);
	BEGIN "HL"
WHILE TRUE DO BEGIN "W"
	IF NOT ANSWER
	   THEN	BEGIN "I"
		OUTSTR(CRLF&
"information available on: S(calar),V(ector),R(otation),F(rame),T(rans),
M(ove/arm reading),I(nput/output),E(dit/miscellanea),D(isplay).
What do you want? (<cr> to come back)" );
		CLRBUF;ANSWER←INCHRW;OUTSTR(CRLF);
	 	END "I";
	IF ANSWER=CR 
	   THEN BEGIN CLRBUF;DONE;END
	ELSE IF ANSWER="D" OR ANSWER="d"
		THEN HLPMSG(29)
	ELSE IF ANSWER="E" OR ANSWER="e"
		THEN BEGIN HLPMSG(18,19);HLPMSG(37,39);END
	ELSE IF ANSWER="F" OR ANSWER="f"
		THEN BEGIN HLPMSG(0,2);HLPMSG(10,17);END
	ELSE IF ANSWER="I" OR ANSWER="i"
		THEN HLPMSG(31,36)
	ELSE IF ANSWER="M" OR ANSWER="m"
		THEN BEGIN HLPMSG(10);HLPMSG(20,25);END
	ELSE IF ANSWER="R" OR ANSWER="r"
		THEN BEGIN HLPMSG(0,2);HLPMSG(5,7);END
	ELSE IF ANSWER="S" OR ANSWER="s"
		THEN HLPMSG(0,4)
	ELSE IF ANSWER="T" OR ANSWER="t"
		THEN BEGIN HLPMSG(0,2);HLPMSG(26,28);END
	ELSE IF ANSWER="V" OR ANSWER="v"
		THEN BEGIN HLPMSG(0,2);HLPMSG(44,49);END
	ELSE PRINT("unrecognized! Try again ",CRLF);
	ANSWER←NULL;
	END "W";
	END "HL";

END "HELP";